cmake_minimum_required(VERSION 3.5)
project(lomiri-terminal-app VERSION 2.0.2 LANGUAGES CXX)

include(FindGettext)
if(NOT GETTEXT_FOUND)
    message(FATAL_ERROR "Could not find gettext")
endif(NOT GETTEXT_FOUND)

set(CMAKE_AUTOMOC ON)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -fno-permissive -pedantic -Wall -Wextra -fPIC")

# Enable QML debugging in debug builds
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DQT_QML_DEBUG ")

# Standard install paths
include(GNUInstallDirs)

option(INSTALL_TESTS "Install the tests on make install" on)
option(CLICK_MODE "Installs to a contained location" on)

set(APP_NAME ${PROJECT_NAME})
set(DESKTOP_FILE "${PROJECT_NAME}.desktop")
set(APP_HARDCODE ${PROJECT_NAME})
set(MAIN_QML lomiri-terminal-app.qml)
set(ICON_FILE terminal-app.svg)
set(SPLASH_FILE terminal-app-splash.svg)
set(AUTOPILOT_DIR lomiri_terminal_app)
set(MANIFEST_PATH "manifest.json.in" CACHE INTERNAL "Relative path to the manifest file")
set(URLS_FILE "${APP_HARDCODE}.url-dispatcher")

if(CLICK_MODE)
    if(NOT DEFINED GIT_SOURCE)
        set(GIT_SOURCE "https://gitlab.com/ubports/development/apps/lomiri-terminal-app.git")
        message("-- Setting GIT_SOURCE to ${GIT_SOURCE}")
    endif(NOT DEFINED GIT_SOURCE)
    # Find out the architecture for package building
    # to determine the plugin's installation path
    execute_process(
        COMMAND dpkg-architecture -qDEB_HOST_MULTIARCH
        OUTPUT_VARIABLE ARCH_TRIPLET
        OUTPUT_STRIP_TRAILING_WHITESPACE
    )
    set(CMAKE_INSTALL_PREFIX /)
    set(CMAKE_INSTALL_BINDIR /)
    set(DATA_DIR /)
    set(DESKTOP_DIR ${DATA_DIR})
    set(URLS_DIR ${DATA_DIR})
    set(ICON ${ICON_FILE})
    set(SPLASH ${SPLASH_FILE})
    set(QT_IMPORTS_DIR "/lib/${ARCH_TRIPLET}")
    set(BIN_DIR /lib/${ARCH_TRIPLET}/bin)
    set(EXEC "lomiri-terminal-app-migrate.py ${APP_NAME}")
    if(NOT GIT_REV)
      execute_process(
        COMMAND git log --format='%h' -1
        OUTPUT_VARIABLE GIT_REV
        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
        OUTPUT_STRIP_TRAILING_WHITESPACE
      )
    endif(NOT GIT_REV)

    execute_process(
      COMMAND dpkg-architecture -qDEB_HOST_ARCH
      OUTPUT_VARIABLE CLICK_ARCH
      OUTPUT_STRIP_TRAILING_WHITESPACE
    )
    configure_file(manifest.json.in ${CMAKE_CURRENT_BINARY_DIR}/manifest.json)
    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/manifest.json terminal.apparmor DESTINATION ${CMAKE_INSTALL_PREFIX})

    # make the click files visible in qtcreator
    file(GLOB CLICK_FILES
         RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
         *.json *.json.in *.apparmor)

    add_custom_target(lomiri-terminal-app_CLICKFiles ALL SOURCES ${CLICK_FILES})
else(CLICK_MODE)
    set(QT_IMPORTS_DIR "${CMAKE_INSTALL_LIBDIR}/qt5/qml")
    set(DATA_DIR ${CMAKE_INSTALL_DATADIR}/${APP_NAME})
    set(ICON ${CMAKE_INSTALL_PREFIX}/${DATA_DIR}/${ICON_FILE})
    set(SPLASH ${CMAKE_INSTALL_PREFIX}/${DATA_DIR}/${SPLASH_FILE})
    set(DESKTOP_DIR ${CMAKE_INSTALL_DATADIR}/applications)
    set(URLS_DIR ${CMAKE_INSTALL_DATADIR}/lomiri-url-dispatcher/urls)
    set(EXEC "${APP_NAME}")
    install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/${APP_NAME}.1 DESTINATION ${CMAKE_INSTALL_DATADIR}/man/man1)
endif(CLICK_MODE)

file(GLOB SRC_FILES
     RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
     *.qml *.js *.png *.svg *.js)
install(FILES ${SRC_FILES}
    DESTINATION ${DATA_DIR})

install(PROGRAMS lomiri-terminal-app-migrate.py DESTINATION ${DATA_DIR})

# Make non compiled files visible in qtcreator
file(GLOB_RECURSE NON_COMPILED_FILES *.qml *.js *.py *.svg *.png *.in *.json *.desktop *.pot *.apparmor qmldir)
add_custom_target(NON_COMPILED_TARGET ALL SOURCES ${NON_COMPILED_FILES})


configure_file(${DESKTOP_FILE}.in.in ${DESKTOP_FILE}.in)

add_custom_target(${DESKTOP_FILE} ALL
    COMMENT "Merging translations into ${DESKTOP_FILE}..."
    COMMAND ${GETTEXT_MSGFMT_EXECUTABLE}
            --desktop --template=${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}.in
            -o ${DESKTOP_FILE}
            -d ${CMAKE_SOURCE_DIR}/po
)

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}
    DESTINATION ${DESKTOP_DIR})

install(FILES ${URLS_FILE} DESTINATION ${URLS_DIR})

# Tests
enable_testing()

add_subdirectory(po)
add_subdirectory(tests)
add_subdirectory(app)
